VBA・Excel 時短！コピペで使える複数行を高速に削除するコード

表の中に不要な行がたくさんある・・・一つ一つ削除するのは面倒だ！

マサヤ

確かに、手作業で消すと時間かかりますよね。

今からコード書くのも面倒だし、短時間で終わらせる方法ないかな～

マサヤ

これ、どうぞ。コピペして使ってください。
メッチャ速く削除できますよ。

結論：高速削除が可能なVBAコードを紹介します！
どうぞコピペしてお使ってください。

どうもマサヤです！

大量データの中にある不要な行を削除するシーン・・・・・・ありますよね。
単純に行を削除するだけなら、Range(cell).Deleteで出来ます。
でも、大量データの行を高速に削除するとなると話が変わってきます。

Range(cell).Deleteで大量の行を削除すると、1行ずつ削除するので時間がかかります。
そんなときは「union」を使うと高速に処理ができます。

さっそくコードを紹介！どうぞ、コピペしてお使いください！
Unionメソッドはこれだけ速いです！
Unionが高速な理由
まとめ：Unionの時短で早く仕事が終わる

さっそくコードを紹介！どうぞ、コピペしてお使いください！

前置き入らないよ～知識あるから、サクッとコードだけ知りたい・・・

そんなアナタと私（忘れた時用）のために、先にコードを紹介します！
適時変更を加えて、お好きに使ってください！

Sub Rows_Delete_Fast()
'===============================================================
'複数行の削除　※高速
'===============================================================
Dim ListLastRow As Long
Dim DeleteRows As Range
Dim ws As Worksheet

'対象シートは適時変更
Set ws = ActiveSheet
'A列を見て最終行を取得　リストがA列以外なら要変更
ListLastRow = ws.Cells(Rows.Count, 1).End(xlUp).Row

'1行目は見出しとみなし、2行目から探査
For i = 2 To ListLastRow
    'Rangeに削除対象行を格納　※今回はB列が空白なら削除。
    If IsEmpty(ws.Cells(i, 2)) Then
        '初回のみ
        If DeleteRows Is Nothing Then
            Set DeleteRows = ws.Rows(i).EntireRow
        '2回目以降は追加
        Else
            Set DeleteRows = Union(DeleteRows, ws.Rows(i).EntireRow)
        End If
    End If
Next

'削除対象行が1つでもあれば行削除を実施
If Not DeleteRows Is Nothing Then DeleteRows.Delete

End Sub